Works in APL2 but not in Dyalog APL

[anilkasat]

I have written the following code in APL2 on mainframe and it gives me desired results

input1
144 81
544 81
84
85
85
85
124
275
542
544
545
533
135
136
155
156
134
530
84
525
526
249
250 12 12 181 41 159 0000 000000 13124
526 23 52 356 26 213 6213
#.Display input1
.→---------------------------------------------------------.
| .→--. .→-. .→-. .→--. .→-. .→--. .→---. .→-----. .→----. |
| ↓144| ↓ | ↓ | ↓ | ↓81| ↓ | ↓ | ↓ | ↓ | |
| |544| | | | | | | |81| | | | | | | | | |
| | | | | | | | | |84| | | | | | | | | |
| | | | | | | | | |85| | | | | | | | | |
| | | | | | | | | |85| | | | | | | | | |
| | | | | | | | | |85| | | | | | | | | |
| |124| | | | | | | | | | | | | | | | | |
| |275| | | | | | | | | | | | | | | | | |
| |542| | | | | | | | | | | | | | | | | |
| |544| | | | | | | | | | | | | | | | | |
| |545| | | | | | | | | | | | | | | | | |
| |533| | | | | | | | | | | | | | | | | |
| |135| | | | | | | | | | | | | | | | | |
| |136| | | | | | | | | | | | | | | | | |
| |155| | | | | | | | | | | | | | | | | |
| |156| | | | | | | | | | | | | | | | | |
| |134| | | | | | | | | | | | | | | | | |
| |530| | | | | | | | | | | | | | | | | |
| | | | | | | | | |84| | | | | | | | | |
| |525| | | | | | | | | | | | | | | | | |
| |526| | | | | | | | | | | | | | | | | |
| |249| | | | | | | | | | | | | | | | | |
| |250| |12| |12| |181| |41| |159| |0000| |000000| |13124| |
| |526| |23| |52| |356| |26| |213| |6213| | | | | |
| '---' '--' '--' '---' '--' '---' '----' '------' '-----' |
'∊---------------------------------------------------------'
⍴input1
9
⍴¨input1
24 3 24 2 24 2 24 3 24 2 24 3 24 4 24 6 24 5

((∊input1=' ')/∊input1)←'-'

#.Display input1
.→---------------------------------------------------------.
| .→--. .→-. .→-. .→--. .→-. .→--. .→---. .→-----. .→----. |
| ↓144| ↓--| ↓--| ↓---| ↓81| ↓---| ↓----| ↓------| ↓-----| |
| |544| |--| |--| |---| |81| |---| |----| |------| |-----| |
| |---| |--| |--| |---| |84| |---| |----| |------| |-----| |
| |---| |--| |--| |---| |85| |---| |----| |------| |-----| |
| |---| |--| |--| |---| |85| |---| |----| |------| |-----| |
| |---| |--| |--| |---| |85| |---| |----| |------| |-----| |
| |124| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |275| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |542| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |544| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |545| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |533| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |135| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |136| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |155| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |156| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |134| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |530| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |---| |--| |--| |---| |84| |---| |----| |------| |-----| |
| |525| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |526| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |249| |--| |--| |---| |--| |---| |----| |------| |-----| |
| |250| |12| |12| |181| |41| |159| |0000| |000000| |13124| |
| |526| |23| |52| |356| |26| |213| |6213| |------| |-----| |
| '---' '--' '--' '---' '--' '---' '----' '------' '-----' |
'∊---------------------------------------------------------'
⍴input1
9

Basically, I wanted to put '-' in input1 wherever there is a ' '. It worked fine in APL2. But when I try to do the same thing in Dyalog APL, it gives me a syntax error. For the same input1, I need the same output as shown above in Dyalog APL.

((∊input1 =' ')/∊input1 )←'-'
SYNTAX ERROR
((∊input1=' ')/∊input1)←'-'
∧

Can some please share their ideas on what needs to be changed in Dyalog APL in order to achieve the same result with the same input1.

Thanks in advance.

[Morten|Dyalog]

There are a few cases of APL2 "selective specification" which are not supported in Dyalog APL. We are looking at closing this gap, possibly this year - but are not ready to announce this yet.

It is hard to come up with a completely general replacement for this expression, but in your specific case, I believe the following function will do the same thing. It may well be more efficient than the selective specification would be, too - but of course I can't measure that:

      charsubst←{a←⎕UCS ⍺ ⋄ ⎕UCS¨{⍵+(--/a)×⍵=1↑a}⎕UCS¨⍵}
      ' -' charsubst input1

.→---------------------------------------------------------.
| .→--. .→-. .→-. .→--. .→-. .→--. .→---. .→-----. .→----. |
| ↓144| ↓--| ↓--| ↓---| ↓81| ↓---| ↓----| ↓------| ↓-----| |
| |544| |--| |--| |---| |81| |---| |----| |------| |-----| |
...etc...

[anilkasat]

Thanks Morten. This did solve the problem for me. However, I came up with one more solution as well.

Disclose Function

res←Disclose nestarray;i;X
i←1

⍝ you may need to copy from below to EEFALUPDRED for R5 variable

res←0⍴' ' ⍝ prepare res with empty axis for catenation
:Repeat
X←i⊃nestarray ⍝ disclose components one by one from nestarray
((,X=' ')/,X)←'-' ⍝ this you know !!!
res,←⊂X ⍝ pack and catenate each component
i+←1 ⍝ increment for no of components inside nestarray
:Until i>⍴nestarray ⍝ total no of times the increment should be done

Disclose input1 --- gives me the result.

[Phil Last]

Also for performing non-scalar operations on the simple subarrays of an arbitrarily nested structure the dfns workspace has a number of functions (see saw: http://dfns.dyalog.com/n_saw.htm) that might help.

[Veli-Matti]

If I understood the problem correctly, the following might be the solution for this specific case:

      aa←10 10⍴1 2 3 '' 5 6
     ((∊0∊¨⍴¨aa)/,aa)←'-'
     aa
1 2 3 - 5 6 1 2 3 -
5 6 1 2 3 - 5 6 1 2
3 - 5 6 1 2 3 - 5 6
1 2 3 - 5 6 1 2 3 -
5 6 1 2 3 - 5 6 1 2
3 - 5 6 1 2 3 - 5 6
1 2 3 - 5 6 1 2 3 -
5 6 1 2 3 - 5 6 1 2
3 - 5 6 1 2 3 - 5 6
1 2 3 - 5 6 1 2 3 -

..but I have been wrong before.
The enss function in the aforementioned dfns workspace might help, too.

-Veli-Matti

[Morten|Dyalog]

FYI: This example [((∊x=' ')/∊x)←'-'] now works in the latest Beta release of Dyalog Version 13.1. There are still a few cases of selective specification that do not work, we are planning to knock them off during 2012.

[michaelk]

This will be a great enhancement. Looking forward to 13.1.